mirror of
https://codeberg.org/hako/Rosenthal.git
synced 2025-04-05 21:54:32 +00:00
891eb84b38
* rosenthal/packages.scm: New file. * rosenthal/packages/patches/atuin-disable-failing-tests.patch: New file. * rosenthal/packages/rust-crates.scm (atuin-cargo-inputs): New variable. * rosenthal/packages/rust-apps.scm (atuin): New variable. * rosenthal/packages/binaries.scm (atuin-bin): Deprecated by atuin. * README.org (Packages): Update. * etc/manifest: Update.
67 lines
2.6 KiB
Scheme
67 lines
2.6 KiB
Scheme
;;; SPDX-License-Identifier: GPL-3.0-or-later
|
|
;;; Copyright © 2015, 2018 Ludovic Courtès <ludo@gnu.org>
|
|
;;; Copyright © 2025 Maxim Cournoyer <maxim.cournoyer@gmail.com>
|
|
|
|
(define-module (rosenthal packages)
|
|
#:use-module (gnu packages)
|
|
#:use-module (guix diagnostics)
|
|
#:use-module (guix i18n)
|
|
#:use-module (ice-9 match)
|
|
#:use-module (srfi srfi-34)
|
|
#:replace (%patch-path
|
|
search-patch)
|
|
#:export (rosenthal-patches))
|
|
|
|
;;; Commentary:
|
|
;;;
|
|
;;; This module refines the default value of some parameters from (gnu
|
|
;;; packages) and the syntax/procedures using those. This allows
|
|
;;; 'search-paths' and friends to work without any user intervention.
|
|
;;;
|
|
;;; Code:
|
|
|
|
(define %rosenthal-root-directory
|
|
;; This is like %distro-root-directory from (gnu packages), with adjusted
|
|
;; paths.
|
|
(letrec-syntax ((dirname* (syntax-rules ()
|
|
((_ file)
|
|
(dirname file))
|
|
((_ file head tail ...)
|
|
(dirname (dirname* file tail ...)))))
|
|
(try (syntax-rules ()
|
|
((_ (file things ...) rest ...)
|
|
(match (search-path %load-path file)
|
|
(#f
|
|
(try rest ...))
|
|
(absolute
|
|
(dirname* absolute things ...))))
|
|
((_)
|
|
#f))))
|
|
(try ("rosenthal/packages/binaries.scm" rosenthal/ packages/)
|
|
("rosenthal/packages.scm" rosenthal/))))
|
|
|
|
(define %patch-path
|
|
;; Define it after '%package-module-path' so that '%load-path' contains user
|
|
;; directories, allowing patches in $GUIX_PACKAGE_PATH to be found.
|
|
(make-parameter
|
|
(map (lambda (directory)
|
|
(if (string=? directory %rosenthal-root-directory)
|
|
(string-append directory "/rosenthal/packages/patches")
|
|
directory))
|
|
%load-path)))
|
|
|
|
;;; XXX: The following must be redefined to make use of the overridden
|
|
;;; %patch-path parameter above.
|
|
(define (search-patch file-name)
|
|
"Search the patch FILE-NAME. Raise an error if not found."
|
|
(or (search-path (%patch-path) file-name)
|
|
(raise (formatted-message (G_ "~a: patch not found")
|
|
file-name))))
|
|
|
|
;;; XXX: `search-patches' being syntax, it can't be overridden by the module
|
|
;;; system, or so it seems, so we simply rename it.
|
|
(define-syntax-rule (rosenthal-patches file-name ...)
|
|
"Return the list of absolute file names corresponding to each
|
|
FILE-NAME found in %PATCH-PATH."
|
|
(list (search-patch file-name) ...))
|