rosenthal: Add tailscale.

* rosenthal/packages/networking.scm (tailscale): New variable.
* rosenthal/packages/binaries.scm (tailscale-bin): Deprecated by it.
* rosenthal/services/networking.scm (tailscale-configuration)[tailscale]: Use
it.

rosenthal/packages/binaries.scm

@@ -19,7 +19,9 @@
   #:use-module (gnu packages glib)
   #:use-module (gnu packages java)
   #:use-module (gnu packages nss)
-  #:use-module (rosenthal packages rust-apps))
+  #:use-module (rosenthal packages networking)
+  #:use-module (rosenthal packages rust-apps)
+  #:use-module (rosenthal packages web))
 
 (define license
   (@@ (guix licenses) license))
@@ -83,6 +85,9 @@ network and application layer, supporting various proxy and anti-censorship
 protocols out-of-the-box.")
     (license license:gpl3)))
 
+(define-public hugo-bin
+  (deprecated-package "hugo-bin" hugo))
+
 (define-public mihomo-bin
   (package
     (name "mihomo-bin")
@@ -186,47 +191,6 @@ different needs.")
        (release-monitoring-url
         . "https://pkg.cloudflareclient.com/dists/bookworm/main/binary-amd64/Packages")))))
 
-(define-public hugo-bin
-  (package
-    (name "hugo-bin")
-    (version "0.145.0")
-    (source (origin
-              (method url-fetch)
-              (uri (string-append
-                    "https://github.com/gohugoio/hugo" "/releases/download/v"
-                    version "/hugo_extended_" version "_linux-amd64.tar.gz"))
-              (sha256
-               (base32
-                "1r2alw2a3acs99dx89p886p3qbwpds6kpgz510jjiym8dna6hx3w"))))
-    (build-system copy-build-system)
-    (arguments
-     (list #:install-plan #~'(("hugo" "bin/"))
-           #:phases
-           #~(modify-phases %standard-phases
-               (delete 'strip)
-               (add-after 'install 'patch-elf
-                 (lambda _
-                   (let ((hugo (string-append #$output "/bin/hugo")))
-                     (invoke "patchelf" "--set-interpreter"
-                             (string-append #$(this-package-input "glibc")
-                                            #$(glibc-dynamic-linker))
-                             hugo)
-                     (invoke "patchelf" "--set-rpath"
-                             (string-append (ungexp (this-package-input "gcc")
-                                                    "lib")
-                                            "/lib")
-                             hugo)))))))
-    (supported-systems '("x86_64-linux"))
-    (native-inputs (list patchelf-0.16))
-    (inputs (list `(,gcc "lib") glibc))
-    (home-page "https://gohugo.io/")
-    (synopsis "Static site generator")
-    (description
-     "Hugo is a static site generator written in Go, optimized for speed and
-designed for flexibility.")
-    (license license:asl2.0)
-    (properties '((upstream-name . "hugo")))))
-
 (define-public komga-bin
   (package
    (name "komga-bin")
@@ -397,30 +361,7 @@ in sidebar.")
     (properties '((upstream-name . "sing-box")))))
 
 (define-public tailscale-bin
-  (package
-    (name "tailscale-bin")
-    (version "1.82.0")
-    (source (origin
-              (method url-fetch)
-              (uri (string-append "https://pkgs.tailscale.com"
-                                  "/stable/tailscale_" version "_amd64.tgz"))
-              (sha256
-               (base32
-                "0ayc224qr2v04qvppbjlhfvnv360qm4129nwzspcd2929xaqkbf4"))))
-    (build-system copy-build-system)
-    (arguments
-     (list #:install-plan
-           #~'(("." "bin/" #:include ("tailscale" "tailscaled")))))
-    (supported-systems '("x86_64-linux"))
-    (home-page "https://tailscale.com/")
-    (synopsis "Private WireGuard® networks made easy")
-    (description
-     "This package provides @command{tailscale}, which brings an easy and secure
-way to use WireGuard and 2FA.")
-    (license license:bsd-3)
-    (properties
-     '((release-monitoring-url . "https://github.com/tailscale/tailscale/releases")
-       (upstream-name . "tailscale")))))
+  (deprecated-package "tailscale-bin" tailscale))
 
 (define-public wakapi-bin
   (package

rosenthal/packages/networking.scm

@@ -8,6 +8,7 @@
   #:use-module (guix gexp)
   #:use-module (guix git-download)
   #:use-module (guix packages)
+  #:use-module (rosenthal utils download)
   #:use-module (gnu packages golang)
   #:use-module (gnu packages golang-build))
 
@@ -86,3 +87,76 @@ origin can remain as closed as possible.")
      "This package provides a simple tool to plumb HTTP proxy requests through
 a SOCKS5 proxy.")
     (license license:expat)))
+
+(define-public tailscale
+  (package
+    (name "tailscale")
+    (version "1.80.3")
+    (source
+     (origin
+       (method go-vendored-fetch)
+       (uri (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/tailscale/tailscale")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "07s8kwksvd0f9r65zkrhp3sn4jrv0c8g5w0wbiv9qq950l8gdv2h"))))
+       (file-name (git-file-name name version))
+       (sha256
+        (base32
+         "0g2pzazrfl41s1gra2g3ni34ddgw32mb2rjlv8x17g3yc7axdbqa"))
+       (modules '((guix build utils)))
+       (snippet '(delete-file-recursively "tool"))))
+    (build-system go-build-system)
+    (arguments
+     (list
+      #:go go-1.23
+      #:install-source? #f
+      #:import-path "."
+      #:build-flags
+      #~(list "-tags" "ts_include_cli"
+              (string-append
+               "-ldflags="
+               " -X tailscale.com/version.longStamp=v"
+               #$(package-version this-package)
+               " -X tailscale.com/version.shortStamp=v"
+               #$(package-version this-package)))
+      #:test-flags ''("-skip=^TestPackageDocs$")
+      #:test-subdirs ''(".")
+      #:modules
+      '(((guix build gnu-build-system) #:prefix gnu:)
+        (guix build go-build-system)
+        (guix build utils))
+      #:phases
+      #~(modify-phases %standard-phases
+          (replace 'unpack
+            (lambda args
+              (apply (assoc-ref gnu:%standard-phases 'unpack) args)
+              (unsetenv "GO111MODULE")))
+          (replace 'install-license-files
+            (assoc-ref gnu:%standard-phases 'install-license-files))
+          ;; TODO: Fix command references.
+          (replace 'build
+            (lambda* (#:key build-flags parallel-build? #:allow-other-keys)
+              (let* ((njobs (if parallel-build? (parallel-job-count) 1)))
+                (setenv "GOMAXPROCS" (number->string njobs))
+                (for-each
+                 (lambda (pkg)
+                   (apply invoke "go" "build" "-ldflags=-s -w" "-trimpath"
+                          "-o" (string-append #$output "/bin/" pkg)
+                          `(,@build-flags
+                            ,(string-append "tailscale.com/cmd/" pkg))))
+                 '("derper"
+                   "derpprobe"
+                   "tailscale"
+                   "tailscaled"
+                   "tsidp"))))))))
+    (home-page "https://tailscale.com/")
+    (synopsis "Private WireGuard® networks made easy")
+    (description
+     "This package provides @command{tailscale}, which brings an easy and secure
+way to use WireGuard and 2FA.")
+    (license license:bsd-3)))

rosenthal/packages/web.scm

@@ -8,8 +8,10 @@
   #:use-module (guix packages)
   #:use-module (guix download)
   #:use-module (guix git-download)
+  #:use-module (rosenthal utils download)
   #:use-module (guix build-system go)
   #:use-module (gnu packages golang)
+  #:use-module (gnu packages image)
   #:use-module (gnu packages web))
 
 (define-public buku-run-dev
@@ -29,6 +31,75 @@
                  (base32
                   "079ygn39px71bypa54jn4z55iq24lxxcy7jv3ijy08iinqbfvldc")))))))
 
+(define-public hugo
+  (package
+    (name "hugo")
+    (version "0.145.0")
+    (source
+     (origin
+       (method go-vendored-fetch)
+       (uri (origin
+              (method git-fetch)
+              (uri (git-reference
+                    (url "https://github.com/gohugoio/hugo")
+                    (commit (string-append "v" version))))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "19kfij8c1ljfn8xr3mfm5c89fhp62bl0c7rx0i8726jn6dbpl9g5"))))
+       (sha256
+        (base32
+         "10fmva8p4hcbs2kyjggbanrmix1mf1fym549c5zdv80khpppzfnb"))))
+    (build-system go-build-system)
+    (arguments
+     (list
+      #:go go-1.23
+      #:install-source? #f
+      #:import-path "."
+      #:build-flags
+      ''("-tags" "extended withdeploy"
+         "-ldflags=-X github.com/gohugoio/hugo/common/hugo.vendorInfo=Nonguix")
+      #:test-flags ''("-skip=^TestCommands/mod|^TestCommands/server")
+      #:test-subdirs ''(".")
+      #:modules
+      '(((guix build gnu-build-system) #:prefix gnu:)
+        (guix build go-build-system)
+        (guix build utils))
+      #:phases
+      #~(modify-phases %standard-phases
+          (replace 'unpack
+            (lambda args
+              (apply (assoc-ref gnu:%standard-phases 'unpack) args)
+              (unsetenv "GO111MODULE")))
+          (replace 'install-license-files
+            (assoc-ref gnu:%standard-phases 'install-license-files))
+          (add-after 'unpack 'fix-paths
+            (lambda* (#:key inputs #:allow-other-keys)
+              (setenv "C_INCLUDE_PATH"
+                      (string-append
+                       (getenv "C_INCLUDE_PATH") ":"
+                       (dirname
+                        (dirname
+                         (dirname
+                          (search-input-file inputs "src/dec/alphai_dec.h"))))))
+              (with-directory-excursion "vendor/github.com/bep/gowebp"
+                (substitute* (find-files "internal/libwebp")
+                  (("../../libwebp_src/(.*)\"" _ file)
+                   (string-append (search-input-file inputs file) "\""))))
+              (with-directory-excursion "vendor/github.com/bep/golibsass"
+                (substitute* (find-files "internal/libsass")
+                  (("../../libsass_src/(.*)\"" _ file)
+                   (string-append (search-input-file inputs file) "\"")))))))))
+    (inputs
+     (list (package-source libsass)
+           (package-source libwebp)))
+    (home-page "https://gohugo.io/")
+    (synopsis "Static site generator")
+    (description
+     "Hugo is a static site generator written in Go, optimized for speed and
+designed for flexibility.")
+    (license license:asl2.0)))
+
 ;; TODO: Package Forgejo without vendored dependencies.
 (define-public forgejo
   (package

rosenthal/services/networking.scm

@@ -9,12 +9,12 @@
   #:use-module (guix records)
   #:use-module (gnu packages linux)
   #:use-module (gnu packages networking)
+  #:use-module (rosenthal packages networking)
   #:use-module (gnu services)
   #:use-module (gnu services admin)
   #:use-module (gnu services configuration)
   #:use-module (gnu services dbus)
   #:use-module (gnu services shepherd)
-  #:use-module (rosenthal packages binaries)
   #:export (iwd-configuration
             iwd-service-type
 
@@ -367,7 +367,7 @@ list, power save will be disabled."))
 
 (define-configuration tailscale-configuration
   (tailscale
-   (file-like tailscale-bin)
+   (file-like tailscale)
    "The tailscale package to use.")
 
   (iptables

rosenthal/utils/download.scm

@@ -0,0 +1,50 @@
+;; SPDX-FileCopyrightText: 2025 Hilton Chain <hako@ultrarare.space>
+;;
+;; SPDX-License-Identifier: GPL-3.0-or-later
+
+(define-module (rosenthal utils download)
+  #:use-module (guix gexp)
+  #:use-module (guix packages)
+  #:use-module (guix build-system gnu)
+  #:use-module (guix build-system go)
+  #:export (go-vendored-fetch))
+
+;; NOTE: This approach shouldn't be upstreamed.
+(define* (go-vendored-fetch src hash-algo hash
+                            #:optional name
+                            #:key (system (%current-system))
+                            (go
+                             (module-ref
+                              (resolve-interface '(gnu packages golang))
+                              ;; Use latest Go in Guix.
+                              'go-1.23))
+                            (nss-certs
+                             (module-ref
+                              (resolve-interface '(gnu packages certs))
+                              'nss-certs)))
+  (gexp->derivation
+   (or name
+       (string-append (origin-file-name src) "-vendored"))
+   (with-imported-modules %default-gnu-imported-modules
+     #~(begin
+         (use-modules (guix build gnu-build-system)
+                      (guix build utils))
+         (setenv "GOCACHE" "/tmp/go")
+         (setenv "GOMODCACHE" "/tmp/gomod")
+         (setenv "SSL_CERT_DIR" #+(file-append nss-certs "/etc/ssl/certs"))
+         ;; Support Unicode in file name.
+         (setlocale LC_ALL "C.UTF-8")
+
+         ((assoc-ref %standard-phases 'unpack) #:source #+src)
+         (invoke #+(file-append go "/bin/go") "mod" "vendor")
+         (copy-recursively "." #$output)))
+   #:system system
+   #:hash-algo hash-algo
+   #:hash hash
+   ;; Is a directory.
+   #:recursive? #t
+   ;; Honor the user's proxy and locale settings.
+   #:leaked-env-vars '("http_proxy" "https_proxy"
+                       "LC_ALL" "LC_MESSAGES" "LANG"
+                       "COLUMNS")
+   #:local-build? #t))